Cómo extraer un número de una cadena en Excel

Al importar datos a Excel, puede ser necesario separarlos. Aprenda cómo extraer un número de una cadena en Excel usando esta guía.

Excel es una hoja de cálculo poderosa, pero no hace milagros. Si está importando datos y esos datos son un desastre, Excel no puede hacer mucho con ellos. Por ejemplo, si tiene valores agregados a otros caracteres como parte de una cadena, no puede realizar cálculos con ellos a menos que los extraiga primero.

Afortunadamente, es posible hacer precisamente eso, aunque puede ser más complicado de lo que piensas. Vea cómo extraer un número de una cadena en Excel.

Cómo extraer un número del final de una cadena usando Flash Fill

Una forma rápida y fácil de extraer un número del final de una cadena es usar Excel Relleno instantáneo recurso. Esta característica le permite llenar rápidamente un rango de celdas según el patrón detectado en una celda específica. Una desventaja de este método es que requiere que usted mismo haga la primera extracción, y si solo desea extraer un número de una sola cadena, no será útil.

En la mayoría de los casos, Flash Fill puede extraer correctamente el número del final de una cadena, aunque no es infalible, por lo que siempre debe verificar los resultados con cuidado. Si no funciona correctamente, intente completar manualmente las dos o tres primeras celdas en lugar de solo la primera.

Para extraer un número del final de una cadena usando Flash Fill:

1. Seleccione la celda junto a la primera celda que contiene sus cadenas.
   
2. Introduzca el número que aparece al final de la cadena.
   
3. Si todos sus datos están en una columna continua sin espacios, seleccione la celda directamente debajo de la que acaba de ingresar el número.
   
4. Si sus datos tienen espacios en algunas líneas, seleccione la primera celda y todas las celdas debajo de las cuales desea extraer números, incluidas las líneas en blanco.
   
5. Prensa Control+E en Windows o Cmd+E en Mac para ejecutar la función Flash Fill.
6. Las celdas restantes se llenarán automáticamente según el patrón detectado por Excel. En la mayoría de los casos, los números del final de la cadena se extraerán correctamente.
   

Cómo extraer un número del final de una cadena usando una fórmula

Una desventaja de usar el método Flash Fill es que requiere que usted mismo extraiga números de la cadena para la primera línea. Es posible extraer un número del final de una cadena usando una fórmula, aunque la fórmula es bastante compleja.

Para extraer un número del final de una cadena usando una fórmula:

1. Haga clic en la celda donde desea que aparezca el número extraído.
2. Ingrese la siguiente fórmula, reemplazando ‘B2’ con la celda que contiene su cadena:

   =VALUE(RIGHT(B2,LEN(B2)-MAX(IF(ISNUMBER(MID(B2,ROW(INDIRECT("1:"&LEN(B2))),1)*1)=FALSE,ROW(INDIRECT("1:"&LEN(B2))),0))))

3. Prensa Digitar.
4. El número debe extraerse de la cadena.
5. Para aplicar la fórmula a las celdas restantes, haga clic en el controlador de arrastre en la esquina inferior derecha de la celda.
   
6. Arrastre hacia abajo sobre las celdas donde desea que se replique la fórmula.
   
7. Suelte el mouse y la fórmula se copiará en las celdas seleccionadas.
8. Estas celdas ahora deberían contener los números extraídos.
   
9. Cualquier celda sin una cadena para extraer devolverá un error. Si desea devolver una celda vacía, puede usar la fórmula:

   =IFERROR(VALUE(RIGHT(B2,LEN(B2)-MAX(IF(ISNUMBER(MID(B2,ROW(INDIRECT("1:"&LEN(B2))),1)*1)=FALSE,ROW(INDIRECT("1:"&LEN(B2))),0)))),"")

10. Cualquier celda vacía ahora devolverá un espacio en blanco.
    

Tal vez se pregunte qué hace esta fórmula. En resumen, genera una matriz con la misma longitud que la cadena. Coloca cada uno de los caracteres de cadena en esta matriz en orden. Luego evalúa cada uno de esos caracteres para ver si son un número o no. Cualquier carácter que sea un número se convierte a cero. Cualquier carácter que no sea un número se convierte en un número que representa su posición en la cadena.

Por ejemplo, AB5HG23 se convertiría en 1, 2, 0, 4, 5, 0, 0. Luego busca el valor más alto en esa lista, que es la posición del último carácter que no es un número. Finalmente, devuelve todos los caracteres después de ese punto, que son los números al final de la cadena. La función VALOR vuelve a convertirlo en un número. Sencillo, ¿verdad?

Cómo extraer un número desde el principio de una cadena usando Flash Fill

También puede usar Flash Fill para extraer un número desde el comienzo de una cadena, completando el primer ejemplo usted mismo y dejando que Excel se salga del patrón.

Para extraer un número desde el principio de una cadena usando Flash Fill:

1. Seleccione la celda a la derecha de la primera cadena que contiene un número que desea extraer.
2. Introduzca el número que aparece al principio de la cadena.
   
3. Si todos sus datos están en una columna continua sin espacios, seleccione la celda directamente debajo de ella.
   
4. Si sus datos tienen espacios, seleccione la primera celda y todas las celdas debajo de las cuales desea extraer números, incluidas las filas en blanco.
   
5. Prensa Control+E en Windows o Cmd+E en Mac para iniciar Flash Fill.
6. Las celdas seleccionadas ahora deberían mostrar los números extraídos.
   

Cómo extraer un número desde el principio de una cadena usando una fórmula

También puede usar una fórmula para extraer un número desde el principio de una cadena. Esto funciona de manera similar a la fórmula de la sección anterior, pero encuentra la posición del primer carácter no numérico y devuelve todos los caracteres anteriores.

Para extraer un número desde el principio de una cadena usando una fórmula:

1. Seleccione la celda donde desea que aparezca el número extraído.
2. Ingrese la siguiente fórmula, reemplazando ‘B18’ con la celda que contiene su cadena:

   =VALUE(LEFT(B18,MATCH(FALSE,ISNUMBER(MID(B18,ROW(INDIRECT("1:"&LEN(B18)+1)),1)*1),0)-1))

3. Prensa Digitar y se extraerá el número.
   
4. Puede usar autocompletar en Excel para copiar la fórmula a cualquier otra celda que necesite.
5. Si desea que cualquier fila vacía devuelva un resultado vacío, use la siguiente fórmula:

   =IFERROR(VALUE(LEFT(B18,MATCH(FALSE,ISNUMBER(MID(B18,ROW(INDIRECT("1:"&LEN(B18)+1)),1)*1),0)-1)),"")

Cómo extraer números de cualquier parte de una cadena usando Flash Fill

Como se mencionó anteriormente, es posible que Flash Fill no funcione si la primera celda no coincide con la forma de algunas de las otras celdas. En este caso, puede ser necesario calcular manualmente dos o tres celdas antes de que Flash Fill proporcione el resultado requerido.

Para extraer números de cualquier parte de una cadena usando Flash Fill:

1. En la celda junto a la primera cadena, escriba manualmente los números que están en la cadena.
   
2. Si todos sus datos están en una columna continua, seleccione la celda directamente debajo de ella.
   
3. Si sus datos tienen algunos espacios en blanco, seleccione la primera celda y todas las celdas debajo de las cuales desea extraer números, incluidas las filas en blanco.
   
4. Prensa Control+E en Windows o Cmd+E en Mac para iniciar Flash Fill.
5. Las celdas ahora deben llenarse con los números extraídos.
   

Cómo extraer números de cualquier parte de una cadena usando una fórmula

Puede usar una fórmula para extraer todos los números de una cadena, sin importar dónde aparezcan.

Para extraer números de cualquier parte de una cadena usando una fórmula:

1. Seleccione la celda donde desea que aparezca el número extraído.
2. Ingrese la siguiente fórmula, reemplazando ‘B9’ con la celda que contiene su cadena:

   =SUMPRODUCT(MID(0&B9,LARGE(INDEX(ISNUMBER(--MID(B9,ROW(INDIRECT("1:"&LEN(B9))),1))*ROW(INDIRECT("1:"&LEN(B9))),0),ROW(INDIRECT("1:"&LEN(B9))))+1,1)*10^ROW(INDIRECT("1:"&LEN(B9)))/10)

3. Su fórmula debe extraer todos los números de la cadena.
   
4. Si desea que cualquier celda en blanco devuelva una celda vacía en lugar de cero, use esta fórmula:

   =IFERROR(SUMPRODUCT(MID(0&B9,LARGE(INDEX(ISNUMBER(--MID(B9,ROW(INDIRECT("1:"&LEN(B9))),1))*ROW(INDIRECT("1:"&LEN(B9))),0),ROW(INDIRECT("1:"&LEN(B9))))+1,1)*10^ROW(INDIRECT("1:"&LEN(B9)))/10),"")

5. Puede usar la función de autocompletar para aplicar la fórmula a cualquier otra celda de su hoja de trabajo.
6. Cualquier cadena que no contenga números devolverá un cero. Puede aprender cómo convertir un cero en un guión en Excel si desea cambiar eso.

Amplíe sus habilidades de Excel

Aprender a extraer un número de una cadena en Excel puede ayudarlo a extraer rápidamente los datos necesarios de una lista de cadenas. Si bien las fórmulas necesarias pueden ser complejas, no es necesario que comprenda exactamente cómo funcionan; solo ellos lo hacen!

Hay trucos de Excel más útiles que puede aprender para llevar sus habilidades al siguiente nivel. Puede aprender cómo contar celdas con texto o cómo calcular la edad de alguien a partir de su fecha de nacimiento. Incluso puede crear un generador de números aleatorios en Excel.